RSSModify 2 plugins for vip system

[MYGO.pl]

I want this code in

PHP Code:

---

/* VSPluginNameItem v1.0 */

#include <amxmodx>
#include <VIPSystem>

#define ACCESS_FLAG VIP_FLAG_C

new curItem

public plugin_init() 
{
    register_plugin("VSPluginNameItem", "1.0", "Author")
    
    curItem = VSRegisterItem("Item Name", ACCESS_FLAG)
}

public VSItemSelected(id, itemid)
{
    if (itemid == curItem)
    {
        // code...
    }
    
    return PLUGIN_HANDLED;
} 


---

in the following plugins:


Glow:

PHP Code:

---

/* Sublime AMXX Editor v2.2 */

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <colorchat>

#define iRandom random_num(10, 255) // Used to set random colors.

#pragma semicolon 1

new const szVersion[] = "2.0.2";
new const szLangData[] = "glowmenulang.txt";

#if AMXX_VERSION_NUM < 200
new szTemp[50];
#endif

// say & say_team commands.
new const szCommands[][] = {
    "/glowmenu",
    "/gm",
    "/glow",
    "!glowmenu",
    "!gm",
    "!glow"
};

new szAimCommands[][] = {
    "/am",
    "/aim",
    "/aimglow",
    "!am",
    "!aim",
    "!aimglow"
};

// ML Support for menu's.
new const szMainMenuText[][] = {
    "MENU_GLOW_TARGET",
    "MENU_GLOW_SELF",
    "MENU_ALL_RANDOM",
    "MENU_GLOW_ALL",
    "MENU_REMOVE_GLOW",
    "MENU_GLOW_TS",
    "MENU_GLOW_CT",
    "MENU_GLOW_AIM"
};

new const szRemoveMenuText[][] = {
    "MENU_REMOVE_OWN_GLOW",
    "MENU_REMOVE_PLAYER_GLOW",
    "MENU_REMOVE_ALL_GLOW",
    "MENU_REMOVE_TS_GLOW",
    "MENU_REMOVE_CT_GLOW",
    "MENU_REMOVE_AIM"
};

new Array:aColorInfo;

// Used to find player later on.
new iGlowTarget[33]; // Declare global since we have to enter one more menu.

new iColorSize;

// pCvars
new pAdminsOnly;
new pMessages;

// bools
new bool:bGlowTarget[33];
new bool:bGlowAll[33];
new bool:bGlowTs[33];
new bool:bGlowCts[33];
new bool:bGlowAim[33];

public plugin_init() {
    register_plugin("Advanced Glow Menu", szVersion, "NapoleoN#");

    register_dictionary(szLangData); // Register our ML File.

    #if AMXX_VERSION_NUM < 200
    new szChat[150];
    #endif

    for(new i; i < sizeof(szCommands); i++) {
        #if AMXX_VERSION_NUM < 200
        formatex(szChat, charsmax(szChat), "say %s", szCommands[i]);
        register_clcmd(szChat, "CheckSettings");
        formatex(szChat, charsmax(szChat), "say_team %s", szCommands[i]);
        register_clcmd(szChat, "CheckSettings");
        #else
        register_clcmd(fmt("say %s", szCommands[i]), "CheckSettings");
        register_clcmd(fmt("say_team %s", szCommands[i]), "CheckSettings");
        #endif
    }

    for(new i; i < sizeof(szAimCommands); i++) { // Allthough it's the same size as szCommands, seperate it for future updates.
        #if AMXX_VERSION_NUM < 200
        formatex(szChat, charsmax(szChat), "say %s", szAimCommands[i]);
        register_clcmd(szChat, "FormatColorMenu");
        formatex(szChat, charsmax(szChat), "say_team %s", szAimCommands[i]);
        register_clcmd(szChat, "FormatColorMenu");
        #else
        register_clcmd(fmt("say %s", szAimCommands[i]), "SetAimGlow");
        register_clcmd(fmt("say_team %s", szAimCommands[i]), "SetAimGlow");
        #endif
    }

    pAdminsOnly =         register_cvar("glow_adminsonly", "1");
    pMessages =         register_cvar("glow_messages", "1");

    aColorInfo = ArrayCreate(50);
    ReadFile();
}

public plugin_end() {
    ArrayDestroy(aColorInfo);
}

public CheckSettings(id) {
    if(get_user_flags(id) & ADMIN_MENU || !get_pcvar_num(pAdminsOnly)) {
        new iMainMenu;

        #if AMXX_VERSION_NUM < 200
        formatex(szTemp, charsmax(szTemp), "%L", id, "MAIN_MENU_HEADER");
        iMainMenu = menu_create(szTemp, "MainMenuHandler");
        #else
        //iMainMenu = menu_create(fmt("%L", id, "MAIN_MENU_HEADER"), "MainMenuHandler", true);
        iMainMenu = menu_create("MAIN_MENU_HEADER", "MainMenuHandler", true);
        #endif

        for(new i; i < sizeof(szMainMenuText); i++) {
            #if AMXX_VERSION_NUM < 200
            formatex(szTemp, charsmax(szTemp), "%L",  id, szMainMenuText[i]);
            menu_additem(iMainMenu, szTemp);
            #else
            //menu_additem(iMainMenu, fmt("%L", id, szMainMenuText[i]));
            menu_additem(iMainMenu, szMainMenuText[i]);
            #endif
        }
        menu_display(id, iMainMenu);
    }
}

public MainMenuHandler(id, iMainMenu, item) {
    switch(item) {
        case 0: GlowTarget(id);
        case 1: GlowYourSelf(id);
        case 2: GlowAllRandom(id);
        case 3: GlowAll(id);
        case 4: RemoveGlowMenu(id);
        case 5: GlowTs(id);
        case 6: GlowCts(id);
        case 7: GlowAimTarget(id);
    }
    menu_destroy(iMainMenu);
}

public ColorMenuHandler(id, iColorMenu, item) {
    if(item != MENU_EXIT) {
        new szRGB[50], szR[4], szG[4], szB[4], szItem[38], iRed, iGreen, iBlue;

        #if AMXX_VERSION_NUM < 200
        new iAccess, iCallBack;
        menu_item_getinfo(iColorMenu, item, iAccess, szRGB, charsmax(szRGB), _, _, iCallBack);
        #else
        menu_item_getinfo(iColorMenu, item, _, szRGB, charsmax(szRGB));
        #endif

        parse(szRGB, szR, charsmax(szR), szG, charsmax(szG), szB, charsmax(szB), szItem, charsmax(szItem));

        iRed = str_to_num(szR);
        iGreen = str_to_num(szG);
        iBlue = str_to_num(szB);

        if(bGlowTarget[id]) {
            if(is_user_alive(iGlowTarget[id])) {
                new szTargName[32];
                get_user_name(iGlowTarget[id], szTargName, charsmax(szTargName));
                set_user_glow(iGlowTarget[id], iRed, iGreen, iBlue);
                if(get_pcvar_num(pMessages)) {
                    new szName[32];
                    get_user_name(id, szName, charsmax(szName));

                    ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_TARGET", szName, szTargName, szItem);
                }
            }
        }

        else if(bGlowAll[id]) {
            new iPlayers[32], iNum;
            get_players(iPlayers, iNum, "a");

            for(new i; i < iNum; i++) {
                set_user_glow(iPlayers[i], iRed, iGreen, iBlue);
            }

            if(get_pcvar_num(pMessages)) {
                new szName[32];
                get_user_name(id, szName, charsmax(szName));

                ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_GLOW_ALL", szName, szItem);
            }
        }

        else if(bGlowTs[id] || bGlowCts[id]) {
            new iPlayers[32], iNum;
            get_players(iPlayers, iNum, "ae", bGlowTs[id] ? "TERRORIST" : "CT");

            for(new i; i < iNum; i++) {
                set_user_glow(iPlayers[i], iRed, iGreen, iBlue);
            }

            if(get_pcvar_num(pMessages)) {
                new szName[32];
                get_user_name(id, szName, charsmax(szName));

                ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_GLOW_TEAM", szName, bGlowTs[id] ? "Terrorists" : "Counter-Terrorists", szItem);
            }
        }

        else if(bGlowAim[id]) {
            new iTargId, iBody, szName[32], szTargName[32];

            get_user_aiming(id, iTargId, iBody);
            if(iTargId) {
                set_user_glow(iTargId, iRed, iGreen, iBlue);

                if(get_pcvar_num(pMessages)) {
                    get_user_name(id, szName, charsmax(szName));
                    get_user_name(iTargId, szTargName, charsmax(szTargName));

                    ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_GLOW_AIM", szName, iTargId, szItem);
                    ColorChat(0, GREEN, "Target found");
                }
            }

            else {
                ColorChat(id, GREEN, "%L", LANG_PLAYER, "MSG_INVALID_TARGET");
            }
            FormatColorMenu(id);
        }

        else if(is_user_alive(id)) {
            set_user_glow(id, iRed, iGreen, iBlue);
            if(get_pcvar_num(pMessages)) {
                new szName[32];
                get_user_name(id, szName, charsmax(szName));

                ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_GLOWING", szName, szItem);
            }
        }
    }
    else {
        bGlowAim[id] = false;
    }

    ResetBools(id);
    menu_destroy(iColorMenu);
}

public GlowTarget(id) {
    #if AMXX_VERSION_NUM < 200
    FormatPlayerMenu(id, "%L", "CHOOSE_PLAYER_GLOW", "GlowPlayerHandler");
    #else
    FormatPlayerMenu(id, "CHOOSE_PLAYER_GLOW", "GlowPlayerHandler");
    #endif

    bGlowTarget[id] = true;
}

public GlowPlayerHandler(id, iPlayerMenu, item) {
    if(item != MENU_EXIT) {
        new szData[6];

        #if AMXX_VERSION_NUM < 200
        new iAccess, iCallBack;
        menu_item_getinfo(iPlayerMenu, item, iAccess, szData, charsmax(szData), _, _, iCallBack);
        #else
        menu_item_getinfo(iPlayerMenu, item, _, szData, charsmax(szData));
        #endif

        new iUserId = str_to_num(szData);
        iGlowTarget[id] = find_player("k", iUserId);

        if(iGlowTarget[id]) {
            FormatColorMenu(id);
        }
    }

    else {
        bGlowTarget[id] = false;
    }
    menu_destroy(iPlayerMenu);
}

public GlowYourSelf(id) {
    FormatColorMenu(id);
}

public GlowAllRandom(id) {
    new iPlayers[32], iNum;
    get_players(iPlayers, iNum);

    for(new i; i < iNum; i++) {
        set_user_glow(iPlayers[i], iRandom, iRandom, iRandom);
    }

    if(get_pcvar_num(pMessages)) {
        new szName[32];
        get_user_name(id, szName, charsmax(szName));

        ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_RANDOM_GLOW", szName);
    }
}

public GlowAll(id) {
    FormatColorMenu(id);
    bGlowAll[id] = true;
}

public GlowAimTarget(id) {
    FormatColorMenu(id);
    bGlowAim[id] = true;
}

public RemoveGlowMenu(id) {
    new iRemoveMenu;

    #if AMXX_VERSION_NUM < 200
    formatex(szTemp, charsmax(szTemp), "%L", id, "REMOVE_MENU_HEADER");
    iRemoveMenu = menu_create(szTemp, "RemoveGlowHandler");
    #else
    //iRemoveMenu = menu_create(fmt("%L", id, "REMOVE_MENU_HEADER"), "RemoveGlowHandler", true);
    iRemoveMenu = menu_create("REMOVE_MENU_HEADER", "RemoveGlowHandler", true);
    #endif

    for(new i; i < sizeof(szRemoveMenuText); i++) {
        #if AMXX_VERSION_NUM < 200
        formatex(szTemp, charsmax(szTemp), "%L", id, szRemoveMenuText[i]);
        menu_additem(iRemoveMenu, szTemp);
        #else
        //menu_additem(iRemoveMenu, fmt("%L", id, szRemoveMenuText[i]));
        menu_additem(iRemoveMenu, szRemoveMenuText[i]);
        #endif
    }
    menu_display(id, iRemoveMenu);
}

public GlowTs(id) {
    FormatColorMenu(id);
    bGlowTs[id] = true;
}

public GlowCts(id) {
    FormatColorMenu(id);
    bGlowCts[id] = true;
}

public RemoveGlowHandler(id, iRemoveMenu, item) {
    switch(item) {
        case 0: set_user_glow(id);
        case 1: RemoveGlowPlayer(id);
        case 2: RemoveGlowAll(id);
        case 3: RemoveGlowTeam(id, "TERRORIST");
        case 4: RemoveGlowTeam(id, "CT");
        case 5: RemoveGlowAim(id);
    }
    menu_destroy(iRemoveMenu);
}

public RemoveGlowPlayer(id) {
    #if AMXX_VERSION_NUM < 200
    FormatPlayerMenu(id, "%L", "CHOOSE_PLAYER_REMOVE", "RemovePlayerHandler");
    #else
    FormatPlayerMenu(id, "CHOOSE_PLAYER_REMOVE", "RemovePlayerHandler");
    #endif
}

public RemovePlayerHandler(id, iPlayerMenu, item) {
    if(item != MENU_EXIT) {
        new szData[6], szTargName[64];

        #if AMXX_VERSION_NUM < 200
        new iAccess, iCallBack;
        menu_item_getinfo(iPlayerMenu, item, iAccess, szData, charsmax(szData), szTargName, charsmax(szTargName), iCallBack);
        #else
        menu_item_getinfo(iPlayerMenu, item, _, szData, charsmax(szData), szTargName, charsmax(szTargName));
        #endif

        new iUserId = str_to_num(szData);
        new iTarget = find_player("k", iUserId);

        if(iTarget && is_user_alive(iTarget)) {
            set_user_glow(iTarget);
            if(get_pcvar_num(pMessages)) {
                new szName[32];
                get_user_name(id, szName, charsmax(szName));
                get_user_name(iTarget, szTargName, charsmax(szTargName));

                ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_REMOVE_GLOW", szName, szTargName);
            }
        }
    }
    menu_destroy(iPlayerMenu);
}

public RemoveGlowAll(id) {
    new iPlayers[32], iNum;
    get_players(iPlayers, iNum);

    for(new i; i < iNum; i++) {
        set_user_glow(iPlayers[i]);
    }

    if(get_pcvar_num(pMessages)) {
        new szName[32];
        get_user_name(id, szName, charsmax(szName));
        ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_REMOVE_ALL", szName);
    }
}

public RemoveGlowAim(id) {
    new iTargId, iBody, szName[32], szTargName[32];

    get_user_aiming(id, iTargId, iBody);

    if(iTargId) {
        set_user_glow(iTargId);

        if(get_pcvar_num(pMessages)) {
            get_user_name(id, szName, charsmax(szName));
            get_user_name(iTargId, szTargName, charsmax(szTargName));

            ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_REMOVE_AIM", szName, szTargName);
        }
    }

    else {
        ColorChat(id, GREEN, "%L", LANG_PLAYER, "MSG_INVALID_TARGET");
    }
    RemoveGlowMenu(id);
}

public RemoveGlowTeam(id, szTeam[]) {
    new iPlayers[32], iNum;
    get_players(iPlayers, iNum, "ae", szTeam);

    for(new i; i < iNum; i++) {
        set_user_glow(iPlayers[i]);
    }

    new szName[32];
    get_user_name(id, szName, charsmax(szName));

    if(get_pcvar_num(pMessages)) {
        strtolower(szTeam);

        switch(szTeam[0]) {
            case 'c': szTeam[0] = 'C';
            case 't': szTeam[0] = 'T';
        }
        ColorChat(0, GREEN, "%L", LANG_PLAYER, "MSG_REMOVE_TEAM", szName, szTeam);
    }
}

public SetAimGlow(id) {
    if(!bGlowAim[id]) {
        bGlowAim[id] = true;
    }
    FormatColorMenu(id);
}

stock set_user_glow(id, iR = 0, iG = 0, iB = 0) {
    set_user_rendering(id, kRenderFxGlowShell, iR, iG, iB, kRenderNormal, 25);
}

ReadFile() {
    new szFileName[256];
    get_configsdir(szFileName, charsmax(szFileName));
    add(szFileName, charsmax(szFileName), "/GlowMenu.txt");

    new iFilePointer = fopen(szFileName, "rt");
    new szLine[50];

    while(fgets(iFilePointer, szLine, charsmax(szLine))) {
        trim(szLine);

        if(szLine[0] == EOS || szLine[0] == ';' || (szLine[0] == '/' && szLine[1] == '/')) {
            continue;
        }

        ArrayPushString(aColorInfo, szLine);
        iColorSize = ArraySize(aColorInfo);
        log_amx(szLine);
    }
    fclose(iFilePointer);
}

public ResetBools(id) {
    bGlowTarget[id] = false;
    bGlowAll[id] = false;
    bGlowTs[id] = false;
    bGlowCts[id] = false;
}

#if AMXX_VERSION_NUM < 200
public FormatPlayerMenu(id, szHeader[], szData[], szHandler[]) {
#else
public FormatPlayerMenu(id, szHeader[], szHandler[]) {
#endif
    new iPlayerMenu;

    #if AMXX_VERSION_NUM < 200
    formatex(szTemp, charsmax(szTemp), szHeader, id, szData);
    iPlayerMenu = menu_create(szTemp, szHandler);
    #else
    //iPlayerMenu = menu_create(fmt(szHeader, id, szData), szHandler);
    iPlayerMenu = menu_create(szHeader, szHandler, true);
    #endif

    new iPlayers[32], iNum, szName[32], szUserId[32], iPlayer;
    get_players(iPlayers, iNum, "a");

    for(new i; i < iNum; i++) {
        iPlayer = iPlayers[i];
        get_user_name(iPlayer, szName, charsmax(szName));
        num_to_str(get_user_userid(iPlayer), szUserId, charsmax(szUserId));
        menu_additem(iPlayerMenu, szName, szUserId);
    }
    menu_display(id, iPlayerMenu);
}

public FormatColorMenu(id) {
    new iColorMenu;

    #if AMXX_VERSION_NUM < 200
    formatex(szTemp, charsmax(szTemp), "%L", id, "MENU_CHOOSE_COLOR");
    iColorMenu = menu_create(szTemp, "ColorMenuHandler");
    #else
    //iColorMenu = menu_create(fmt("%L", id, "MENU_CHOOSE_COLOR"), "ColorMenuHandler", true);
    iColorMenu = menu_create("MENU_CHOOSE_COLOR", "ColorMenuHandler", true);
    #endif

    new szColor[20], szRGB[20], szColorData[200];
    for(new i; i < iColorSize; i++) {
        ArrayGetString(aColorInfo, i, szColorData, charsmax(szColorData));

        split(szColorData, szColor, charsmax(szColor), szRGB, charsmax(szRGB), " ");
        remove_quotes(szColor);

        formatex(szColorData, charsmax(szColorData), "%s %s", szRGB, szColor);
        menu_additem(iColorMenu, szColor, szColorData);
    }
    menu_display(id, iColorMenu);
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/ 


---

Trail:

PHP Code:

---

#include < amxmodx >
#include < amxmisc >
#include < fakemeta >
#include < hamsandwich >

#pragma semicolon 1

#define PLUGIN_VERSION "1.0.0"

#define TASKID        81732519124

#define TRAIL_ACTIVE 1
#define TRAIL_INACTIVE 0
#define TRAIL_LIFE 15
#define ACCES_FLAG  ADMIN_MENU

new gTrailSprite;
new gTrailRandomColor[ 33 ][ 3 ];
new bPlayerTrailStatus[ 33 ];
new Float:bflNextCheck[ 33 ];
new const gTrailSpriteIndex[] = "sprites/zbeam2.spr";

const IN_MOVING = IN_FORWARD | IN_BACK | IN_MOVELEFT | IN_MOVERIGHT | IN_JUMP;

public plugin_init()
{ 
    register_plugin( "Owner Trail", PLUGIN_VERSION, "tuty" );  
    register_forward( FM_CmdStart, "forward_cmdstart" );
    register_clcmd( "say trail", "cmdMakeOwnerTrail" ); 
    register_clcmd( "say_team trail", "cmdMakeOwnerTrail" );
    register_clcmd( "say /trail", "cmdMakeOwnerTrail" ); 
    register_clcmd( "say_team /trail", "cmdMakeOwnerTrail" );
    
    RegisterHam(Ham_Spawn, "player", "Fwd_Spawn", 1);
}

public plugin_precache()
{ 
    gTrailSprite = precache_model( gTrailSpriteIndex );
}

public client_connect( id )
{ 
    bPlayerTrailStatus[ id ] = TRAIL_INACTIVE;
}

public Fwd_Spawn(id)
{
    if(get_user_flags(id) & ACCES_FLAG)
    {
        bPlayerTrailStatus[id] = TRAIL_ACTIVE;
        
        gTrailRandomColor[ id ][ 0 ] = random_num( 0, 255 );  
        gTrailRandomColor[ id ][ 1 ] = random_num( 0, 255 );  
        gTrailRandomColor[ id ][ 2 ] = random_num( 0, 255 );
        
        set_task(10.0, "change_color", id + TASKID, .flags="b");
    }
}

public change_color(taskid)
{
    new id = taskid - TASKID;
    
    if(!is_user_alive(id))
    {
        remove_task(taskid);
        return;
    }
    
    gTrailRandomColor[ id ][ 0 ] = random_num( 0, 255 );  
    gTrailRandomColor[ id ][ 1 ] = random_num( 0, 255 );  
    gTrailRandomColor[ id ][ 2 ] = random_num( 0, 255 );    
}

public cmdMakeOwnerTrail( id )
{ 
    if( !is_user_alive( id ) )
    {  
        client_print( id, print_chat, "[Trail] Nu poti folosi aceasta comanda cand esti mort!" );  
        return PLUGIN_HANDLED; 
    }  
    if( !( get_user_flags( id ) & ACCES_FLAG ) )
    {  
        client_print( id, print_chat, "[Trail] Nu ai acces la aceasta comanda!" );   
        return PLUGIN_HANDLED; 
    } 
    
    if( bPlayerTrailStatus[ id ] == TRAIL_ACTIVE )
    {  
        
        client_print( id, print_chat, "[Trail] Trailul tau a fost dezactivat!" );  
        
        bPlayerTrailStatus[ id ] = TRAIL_INACTIVE;  
        
        UTIL_KillBeamFollow( id );  
        
        bflNextCheck[ id ] = -5000.0;    
        
        return PLUGIN_HANDLED; 
    }  
    
    if( bPlayerTrailStatus[ id ] == TRAIL_INACTIVE ) 
    {  
        client_print( id, print_chat, "[Trail] Trail activat! Acum ai trail!" );  
        
        bPlayerTrailStatus[ id ] = TRAIL_ACTIVE;    
        
        gTrailRandomColor[ id ][ 0 ] = random_num( 0, 255 );  
        gTrailRandomColor[ id ][ 1 ] = random_num( 0, 255 );  
        gTrailRandomColor[ id ][ 2 ] = random_num( 0, 255 );    
        
        return PLUGIN_HANDLED; 
    }  
    
    return PLUGIN_CONTINUE;
}

public forward_cmdstart( id, handle )
{ 
    if( !is_user_alive( id ) || bPlayerTrailStatus[ id ] == TRAIL_INACTIVE ) 
    {  
        return FMRES_IGNORED; 
    } 
    
    new iButton = get_uc( handle, UC_Buttons ); 
    
    if( !( iButton & IN_MOVING ) ) 
    {
        new Float:flGameTime = get_gametime();   
        if( bflNextCheck[ id ] < flGameTime )
        {   
            UTIL_KillBeamFollow( id );   
            UTIL_BeamFollow( id );
            bflNextCheck[ id ] = flGameTime + ( TRAIL_LIFE / 8 );  
        } 
    }  
    
    return FMRES_IGNORED;
}  

stock UTIL_BeamFollow( const iClient )
{
    message_begin( MSG_BROADCAST, SVC_TEMPENTITY ); 
    write_byte( TE_BEAMFOLLOW ); 
    write_short( iClient );
    write_short( gTrailSprite ); 
    write_byte( TRAIL_LIFE );
    write_byte( 20 ); 
    write_byte( gTrailRandomColor[ iClient ][ 0 ] ); 
    write_byte( gTrailRandomColor[ iClient ][ 1 ] ); 
    write_byte( gTrailRandomColor[ iClient ][ 2 ] ); 
    write_byte( 255 ); 
    message_end();
}
    
stock UTIL_KillBeamFollow( const iClient )
{ 
    message_begin( MSG_BROADCAST, SVC_TEMPENTITY ); 
    write_byte( TE_KILLBEAM );     
    write_short( iClient ); 
    message_end();
} 


---

Przeczytaj cały wpis